GitHub

Linear Reaction-Diffusion Equations

Next, we write a specialised solver for solving linear reaction-diffusion equations. What we produce in this section can also be accessed in FiniteVolumeMethod.LinearReactionDiffusionEquation.

Mathematical Details

To start, let's give the mathematical details. The problems we will be solving take the form

\[\pdv{u}{t} = \div\left[D(\vb x)\grad u\right] + f(\vb x)u.\]

We want to turn this into an equation of the form $\mathrm d\vb u/\mathrm dt = \vb A\vb u + \vb b$ as usual. This takes the same form as our diffusion equation example, except with the extra $f(\vb x)u$ term, which just adds an exta $f(\vb x)$ term to the diagonal of $\vb A$. See the previois sections for further mathematical details.

Implementation

Let us now implement the solver. For constructing $\vb A$, we can use FiniteVolumeMethod.triangle_contributions! as in the previous sections, but we will need an extra function to add $f(\vb x)$ to the appropriate diagonals. We can also reuse apply_dirichlet_conditions!, apply_dudt_conditions, and boundary_edge_contributions! from the diffusion equation example. Here is our implementation.

using FiniteVolumeMethod, SparseArrays, OrdinaryDiffEq, LinearAlgebra
const FVM = FiniteVolumeMethod
function linear_source_contributions!(
        A, mesh, conditions, source_function, source_parameters
    )
    for i in each_solid_vertex(mesh.triangulation)
        if !FVM.has_condition(conditions, i)
            x, y = get_point(mesh, i)
            A[i, i] += source_function(x, y, source_parameters)
        end
    end
    return
end
function linear_reaction_diffusion_equation(
        mesh::FVMGeometry,
        BCs::BoundaryConditions,
        ICs::InternalConditions = InternalConditions();
        diffusion_function,
        diffusion_parameters = nothing,
        source_function,
        source_parameters = nothing,
        initial_condition,
        initial_time = 0.0,
        final_time
    )
    conditions = Conditions(mesh, BCs, ICs)
    n = DelaunayTriangulation.num_solid_vertices(mesh.triangulation)
    Afull = zeros(n + 1, n + 1)
    A = @views Afull[begin:(end - 1), begin:(end - 1)]
    b = @views Afull[begin:(end - 1), end]
    _ic = vcat(initial_condition, 1)
    FVM.triangle_contributions!(
        A, mesh, conditions, diffusion_function, diffusion_parameters
    )
    FVM.boundary_edge_contributions!(
        A, b, mesh, conditions, diffusion_function, diffusion_parameters
    )
    linear_source_contributions!(A, mesh, conditions, source_function, source_parameters)
    FVM.apply_dudt_conditions!(b, mesh, conditions)
    FVM.apply_dirichlet_conditions!(_ic, mesh, conditions)
    FVM.fix_missing_vertices!(A, b, mesh)
    Af = sparse(Afull)
    prob = ODEProblem(MatrixOperator(Af), _ic, (initial_time, final_time))
    return prob
end
linear_reaction_diffusion_equation (generic function with 2 methods)

If you go and look back at the diffusion_equation function from the diffusion equation example, you will see that this is essentially the same function except we now have linear_source_contributions! and source_function and source_parameters arguments.

Let's now test this function. We consider the problem

\[\pdv{T}{t} = \div\left[10^{-3}x^2y\grad T\right] + (x-1)(y-1)T, \quad \vb x \in [0,1]^2,\]

with $\grad T \vdot\vu n = 1$ on the boundary.

using DelaunayTriangulation
tri = triangulate_rectangle(0, 1, 0, 1, 150, 150, single_boundary = true)
mesh = FVMGeometry(tri)
BCs = BoundaryConditions(mesh, (x, y, t, u, p) -> one(x), Neumann)
diffusion_function = (x, y, p) -> p.D * x^2 * y
diffusion_parameters = (D = 1.0e-3,)
source_function = (x, y, p) -> (x - 1) * (y - 1)
initial_condition = [x^2 + y^2 for (x, y) in DelaunayTriangulation.each_point(tri)]
final_time = 8.0
prob = linear_reaction_diffusion_equation(
    mesh, BCs;
    diffusion_function, diffusion_parameters,
    source_function, initial_condition, final_time
)
ODEProblem with uType Vector{Float64} and tType Float64. In-place: true
Non-trivial mass matrix: false
timespan: (0.0, 8.0)
u0: 22501-element Vector{Float64}:
 0.0
 4.504301608035674e-5
 0.00018017206432142696
 0.00040538714472321063
 0.0007206882572857079
 ⋮
 1.9601369307688843
 1.9733345344804287
 1.986622224224134
 2.0
 1.0
sol = solve(prob, Tsit5(); saveat = 2)
retcode: Success
Interpolation: 1st order linear
t: 5-element Vector{Float64}:
 0.0
 2.0
 4.0
 6.0
 8.0
u: 5-element Vector{Vector{Float64}}:
 [0.0, 4.504301608035674e-5, 0.00018017206432142696, 0.00040538714472321063, 0.0007206882572857079, 0.0011260754020089186, 0.0016215485788928425, 0.0022071077879374803, 0.0028827530291428314, 0.0036484843025088956  …  1.8955002026935723, 1.9082473762443133, 1.921084635827215, 1.9340119814422772, 1.9470294130895003, 1.9601369307688843, 1.9733345344804287, 1.986622224224134, 2.0, 1.0]
 [5.392972715241144e-10, 0.00032839693136766843, 0.0012960759990657792, 0.0028772909445736266, 0.005046982038098889, 0.007780761845897448, 0.011054900287088443, 0.014846309987847438, 0.019132531927487165, 0.023891721371031467  …  1.857601258988074, 1.8669187520861237, 1.8756974896164833, 1.8847638874373263, 1.891790587925996, 1.9028816755063156, 1.9023588034293808, 1.9299909658674956, 1.8825037936504059, 1.0]
 [7.916735417539213e-9, 0.002394255277378063, 0.009323370071034556, 0.02042192008254055, 0.03534389913584279, 0.053761876350106534, 0.07536617230272592, 0.09986406790939065, 0.1269790448138673, 0.15645005612239934  …  1.8509136105071595, 1.858591600062336, 1.8664895899891423, 1.8731272794777645, 1.8825835384209604, 1.8841164967411093, 1.9053114153277442, 1.8762173442191818, 1.978490952695331, 1.0]
 [8.716291359760348e-8, 0.01745587228824828, 0.06706791816304723, 0.14494671157302366, 0.24751160642335757, 0.37147055211194413, 0.5138009456452572, 0.6717316202228347, 0.8427259076096068, 1.0244657148949725  …  1.8560527056615168, 1.8629729344642048, 1.8696298851466964, 1.8768276952756366, 1.8824053751208047, 1.8921110896830706, 1.8912408569476595, 1.9171352613990214, 1.8728687859751842, 1.0]
 [8.530436664276855e-7, 0.12726600200660865, 0.48245430288397767, 1.0287720968254588, 1.7333054836766972, 2.5666820729791873, 3.5027585194801256, 4.5183326883131265, 5.592878646428236, 6.708302802132752  …  1.87005262865289, 1.8761847240187421, 1.8825065062351807, 1.8884430769360503, 1.8956204930445018, 1.8997921589345672, 1.9118930626122232, 1.9042189119217992, 1.9487418307409274, 1.0]
using CairoMakie
fig = Figure(fontsize = 38)
for j in eachindex(sol)
    ax = Axis(
        fig[1, j], width = 600, height = 600,
        xlabel = "x", ylabel = "y",
        title = "t = $(sol.t[j])"
    )
    tricontourf!(
        ax, tri, sol.u[j], levels = 0:0.1:1, extendlow = :auto,
        extendhigh = :auto, colormap = :turbo
    )
    tightlimits!(ax)
end
resize_to_layout!(fig)
fig
Example block output

Here is how we could convert this into an FVMProblem. Note that the Neumann boundary conditions are expressed as $\grad T\vdot\vu n = 1$ above, but for FVMProblem we need them in the form $\vb q\vdot\vu n = \ldots$. For this problem, $\vb q=-D\grad T$, which gives $\vb q\vdot\vu n = -D$.

_BCs = BoundaryConditions(
    mesh, (x, y, t, u, p) -> -p.D(x, y, p.Dp), Neumann;
    parameters = (D = diffusion_function, Dp = diffusion_parameters)
)
fvm_prob = FVMProblem(
    mesh,
    _BCs;
    diffusion_function = let D = diffusion_function
        (x, y, t, u, p) -> D(x, y, p)
    end,
    diffusion_parameters = diffusion_parameters,
    source_function = let S = source_function
        (x, y, t, u, p) -> S(x, y, p) * u
    end,
    final_time = final_time,
    initial_condition = initial_condition
)
fvm_sol = solve(fvm_prob, Tsit5(), saveat = 2.0)

for j in eachindex(fvm_sol)
    ax = Axis(
        fig[2, j], width = 600, height = 600,
        xlabel = "x", ylabel = "y",
        title = "t = $(fvm_sol.t[j])"
    )
    tricontourf!(
        ax, tri, fvm_sol.u[j], levels = 0:0.1:1,
        extendlow = :auto, extendhigh = :auto, colormap = :turbo
    )
    tightlimits!(ax)
end
resize_to_layout!(fig)
fig
Example block output

Using the Provided Template

The above code is implemented in LinearReactionDiffusionEquation in FiniteVolumeMethod.jl.

prob = LinearReactionDiffusionEquation(
    mesh, BCs;
    diffusion_function, diffusion_parameters,
    source_function, initial_condition, final_time
)
sol = solve(prob, Tsit5(); saveat = 2)
retcode: Success
Interpolation: 1st order linear
t: 5-element Vector{Float64}:
 0.0
 2.0
 4.0
 6.0
 8.0
u: 5-element Vector{Vector{Float64}}:
 [0.0, 4.504301608035674e-5, 0.00018017206432142696, 0.00040538714472321063, 0.0007206882572857079, 0.0011260754020089186, 0.0016215485788928425, 0.0022071077879374803, 0.0028827530291428314, 0.0036484843025088956  …  1.8955002026935723, 1.9082473762443133, 1.921084635827215, 1.9340119814422772, 1.9470294130895003, 1.9601369307688843, 1.9733345344804287, 1.986622224224134, 2.0, 1.0]
 [5.392972715241144e-10, 0.00032839693136766843, 0.0012960759990657792, 0.0028772909445736266, 0.005046982038098889, 0.007780761845897448, 0.011054900287088443, 0.014846309987847438, 0.019132531927487165, 0.023891721371031467  …  1.857601258988074, 1.8669187520861237, 1.8756974896164833, 1.8847638874373263, 1.891790587925996, 1.9028816755063156, 1.9023588034293808, 1.9299909658674956, 1.8825037936504059, 1.0]
 [7.916735417539213e-9, 0.002394255277378063, 0.009323370071034556, 0.02042192008254055, 0.03534389913584279, 0.053761876350106534, 0.07536617230272592, 0.09986406790939065, 0.1269790448138673, 0.15645005612239934  …  1.8509136105071595, 1.858591600062336, 1.8664895899891423, 1.8731272794777645, 1.8825835384209604, 1.8841164967411093, 1.9053114153277442, 1.8762173442191818, 1.978490952695331, 1.0]
 [8.716291359760348e-8, 0.01745587228824828, 0.06706791816304723, 0.14494671157302366, 0.24751160642335757, 0.37147055211194413, 0.5138009456452572, 0.6717316202228347, 0.8427259076096068, 1.0244657148949725  …  1.8560527056615168, 1.8629729344642048, 1.8696298851466964, 1.8768276952756366, 1.8824053751208047, 1.8921110896830706, 1.8912408569476595, 1.9171352613990214, 1.8728687859751842, 1.0]
 [8.530436664276855e-7, 0.12726600200660865, 0.48245430288397767, 1.0287720968254588, 1.7333054836766972, 2.5666820729791873, 3.5027585194801256, 4.5183326883131265, 5.592878646428236, 6.708302802132752  …  1.87005262865289, 1.8761847240187421, 1.8825065062351807, 1.8884430769360503, 1.8956204930445018, 1.8997921589345672, 1.9118930626122232, 1.9042189119217992, 1.9487418307409274, 1.0]

Here is a benchmark comparison of LinearReactionDiffusionEquation versus FVMProblem.

using BenchmarkTools
using Sundials
@btime solve($prob, $CVODE_BDF(linear_solver=:GMRES); saveat=$2);
  48.360 ms (1087 allocations: 1.58 MiB)
@btime solve($fvm_prob, $CVODE_BDF(linear_solver=:GMRES); saveat=$2);
  163.686 ms (83267 allocations: 90.84 MiB)

Just the code

An uncommented version of this example is given below. You can view the source code for this file here.

using FiniteVolumeMethod, SparseArrays, OrdinaryDiffEq, LinearAlgebra
const FVM = FiniteVolumeMethod
function linear_source_contributions!(
        A, mesh, conditions, source_function, source_parameters
    )
    for i in each_solid_vertex(mesh.triangulation)
        if !FVM.has_condition(conditions, i)
            x, y = get_point(mesh, i)
            A[i, i] += source_function(x, y, source_parameters)
        end
    end
    return
end
function linear_reaction_diffusion_equation(
        mesh::FVMGeometry,
        BCs::BoundaryConditions,
        ICs::InternalConditions = InternalConditions();
        diffusion_function,
        diffusion_parameters = nothing,
        source_function,
        source_parameters = nothing,
        initial_condition,
        initial_time = 0.0,
        final_time
    )
    conditions = Conditions(mesh, BCs, ICs)
    n = DelaunayTriangulation.num_solid_vertices(mesh.triangulation)
    Afull = zeros(n + 1, n + 1)
    A = @views Afull[begin:(end - 1), begin:(end - 1)]
    b = @views Afull[begin:(end - 1), end]
    _ic = vcat(initial_condition, 1)
    FVM.triangle_contributions!(
        A, mesh, conditions, diffusion_function, diffusion_parameters
    )
    FVM.boundary_edge_contributions!(
        A, b, mesh, conditions, diffusion_function, diffusion_parameters
    )
    linear_source_contributions!(A, mesh, conditions, source_function, source_parameters)
    FVM.apply_dudt_conditions!(b, mesh, conditions)
    FVM.apply_dirichlet_conditions!(_ic, mesh, conditions)
    FVM.fix_missing_vertices!(A, b, mesh)
    Af = sparse(Afull)
    prob = ODEProblem(MatrixOperator(Af), _ic, (initial_time, final_time))
    return prob
end

using DelaunayTriangulation
tri = triangulate_rectangle(0, 1, 0, 1, 150, 150, single_boundary = true)
mesh = FVMGeometry(tri)
BCs = BoundaryConditions(mesh, (x, y, t, u, p) -> one(x), Neumann)
diffusion_function = (x, y, p) -> p.D * x^2 * y
diffusion_parameters = (D = 1.0e-3,)
source_function = (x, y, p) -> (x - 1) * (y - 1)
initial_condition = [x^2 + y^2 for (x, y) in DelaunayTriangulation.each_point(tri)]
final_time = 8.0
prob = linear_reaction_diffusion_equation(
    mesh, BCs;
    diffusion_function, diffusion_parameters,
    source_function, initial_condition, final_time
)

sol = solve(prob, Tsit5(); saveat = 2)

using CairoMakie
fig = Figure(fontsize = 38)
for j in eachindex(sol)
    ax = Axis(
        fig[1, j], width = 600, height = 600,
        xlabel = "x", ylabel = "y",
        title = "t = $(sol.t[j])"
    )
    tricontourf!(
        ax, tri, sol.u[j], levels = 0:0.1:1, extendlow = :auto,
        extendhigh = :auto, colormap = :turbo
    )
    tightlimits!(ax)
end
resize_to_layout!(fig)
fig

_BCs = BoundaryConditions(
    mesh, (x, y, t, u, p) -> -p.D(x, y, p.Dp), Neumann;
    parameters = (D = diffusion_function, Dp = diffusion_parameters)
)
fvm_prob = FVMProblem(
    mesh,
    _BCs;
    diffusion_function = let D = diffusion_function
        (x, y, t, u, p) -> D(x, y, p)
    end,
    diffusion_parameters = diffusion_parameters,
    source_function = let S = source_function
        (x, y, t, u, p) -> S(x, y, p) * u
    end,
    final_time = final_time,
    initial_condition = initial_condition
)
fvm_sol = solve(fvm_prob, Tsit5(), saveat = 2.0)

for j in eachindex(fvm_sol)
    ax = Axis(
        fig[2, j], width = 600, height = 600,
        xlabel = "x", ylabel = "y",
        title = "t = $(fvm_sol.t[j])"
    )
    tricontourf!(
        ax, tri, fvm_sol.u[j], levels = 0:0.1:1,
        extendlow = :auto, extendhigh = :auto, colormap = :turbo
    )
    tightlimits!(ax)
end
resize_to_layout!(fig)
fig

prob = LinearReactionDiffusionEquation(
    mesh, BCs;
    diffusion_function, diffusion_parameters,
    source_function, initial_condition, final_time
)
sol = solve(prob, Tsit5(); saveat = 2)

This page was generated using Literate.jl.